cs-os/scripts/Player.gd

extends CharacterBody3D

const SENSETIVITY = 0.009;

enum Class_type {
	Spectator = 0,
	Astra = 1,
	BlackArch = 2,
	Kali = 3,
	Debian = 4,
	Arch = 5,
	Windows11 = -1,
	WindowsServer = -2,
	MacOS = -3,
	WindowsXP = -4,
	Windows10 = -5
}

var properties = {
	HP = 100,
	AP = 100,
	HACK = 1.0,
	class_type = 0,
	is_playable = false,
	internal_id = 0
}

var speed = 0
var walk = 0
var run = 0
var jump = 0
var gravity = 0
var game_settings
var client_settings

@onready var head = $Head
@onready var camera = $Head/Camera
@onready var playerCharacterBody = $"."


func set_player_name (n):
	$"..".name = n

func set_internal_id(id):
	print("Setting internal_id to " + str(id))
	properties["internal_id"] = id

func set_is_playable(value):
	properties["is_playable"] = value

func _ready():
	if (!properties["is_playable"]): return
	camera.make_current()
	playerCharacterBody.up_direction = Vector3.UP;
	Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)

func _unhandled_input(event):
	if (!properties["is_playable"]): return
	if event is InputEventMouseMotion:
		head.rotate_y(-event.relative.x * SENSETIVITY)
		camera.rotate_x(-event.relative.y * SENSETIVITY)
		camera.rotation.x = clamp(camera.rotation.x, deg_to_rad(-50), deg_to_rad(60))
		Networking.rotate_camera_client.rpc_id(1, multiplayer.get_unique_id(), head.rotation.y, camera.rotation.x)
		
func _physics_process(delta):
	if (!properties["is_playable"]): return
	if (game_settings == null): return
	if (multiplayer.multiplayer_peer == null):
		properties["is_playable"] = false
	if not is_on_floor():
		velocity.y -= 4 * gravity * delta

	var input_dir = Input.get_vector("left", "right", "forward", "backward")
	var direction = (head.transform.basis * Vector3(input_dir.x, 0, input_dir.y)).normalized()
	
	if is_on_floor():
		if Input.is_action_just_pressed("jump"):
			velocity.y = jump
		if Input.is_action_pressed("run"):
			speed = run
		else:
			speed = walk
		if direction:
			velocity.x = direction.x * speed
			velocity.z = direction.z * speed
		else:
			velocity.x = lerp(velocity.x, direction.x * speed, delta * 4)
			velocity.z = lerp(velocity.z, direction.z * speed, delta * 4)
	else:
		velocity.x = lerp(velocity.x, direction.x * speed, delta)
		velocity.z = lerp(velocity.z, direction.z * speed, delta)
	move_and_slide()
	if (!multiplayer.is_server()):
		Networking.move_client.rpc_id(1, multiplayer.get_unique_id(), $".".position)
		#print("I am " + $"..".name +", belonging of " + str(multiplayer.get_unique_id()) + ", with internal ID: " + str(properties["internal_id"]))

@rpc ("authority", "call_remote", "unreliable")
func move_puppet(p: Vector3, i_id):
	if (i_id == properties["internal_id"]):
		playerCharacterBody.position = p

@rpc ("authority", "call_remote", "reliable")
func set_game_settings(s):
	if(!properties["is_playable"]): return
	print("Got settings from server: " + str(s))
	game_settings = s
	gravity = game_settings["moving"]["gravity"]
	walk = game_settings["moving"]["walk"]
	run = game_settings["moving"]["run"]
	jump = game_settings["moving"]["jump"]

@rpc("authority", "call_remote", "unreliable")
func rotate_camera_puppet(rot, i_id):
	if (i_id == properties["internal_id"]):
		head.rotation.y = rot.y
		camera.rotation.x = rot.x