cmake_minimum_required(VERSION 3.10)

project(checks-parser VERSION 0.0.4 LANGUAGES CXX)

option(BUILD_TRANSLATIONS "Build translations?" ON)
option(BUILD_EMAIL_TO_TEXT_MODE "Build email-to-text mode?" ON)
option(BUILD_OCR_MODE "Build OCR mode?" ON)
option(BUILD_OFD_LOCAL_QR_SCAN "Build OFDs' local qr scanner?" ON)
option(BUILD_OFD_BINARYEYE_SCAN "Build OFDs' binaryeye scanner?" ON)

if (NOT (BUILD_EMAIL_TO_TEXT_MODE OR BUILD_OCR_MODE OR BUILD_OFD_LOCAL_QR_SCAN OR BUILD_OFD_BINARYEYE_SCAN))
    message(FATAL_ERROR "You must specify at least one of the modes of data input!")
    return()
endif()

if (BUILD_TRANSLATIONS)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_TRANSLATIONS)
    else()
        add_compile_definitions(BUILD_TRANSLATIONS)
    endif()
endif()

if (BUILD_OFD_LOCAL_QR_SCAN OR BUILD_OFD_BINARYEYE_SCAN)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_OFD_MODE)
    else()
        add_compile_definitions(BUILD_OFD_MODE)
    endif()
endif()

if (BUILD_EMAIL_TO_TEXT_MODE)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_EMAIL_TO_TEXT_MODE)
    else()
        add_compile_definitions(BUILD_EMAIL_TO_TEXT_MODE)
    endif()
endif()
if (BUILD_OCR_MODE)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_OCR_MODE)
    else()
        add_compile_definitions(BUILD_OCR_MODE)
    endif()
endif()
if (BUILD_OFD_LOCAL_QR_SCAN)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_OFD_LOCAL_QR_SCAN)
    else()
        add_compile_definitions(BUILD_OFD_LOCAL_QR_SCAN)
    endif()
endif()
if (BUILD_OFD_BINARYEYE_SCAN)
    if(CMAKE_VERSION VERSION_LESS 3.12)
        add_definitions(-DBUILD_OFD_BINARYEYE_SCAN)
    else()
        add_compile_definitions(BUILD_OFD_BINARYEYE_SCAN)
    endif()
endif()

SET(CMAKE_BUILD_TYPE Debug)
SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC OFF)
set(CMAKE_INCLUDE_CURRENT_DIR ON)
set(CMAKE_AUTOUIC_SEARCH_PATHS scenes)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(Qt5Core REQUIRED)
if (BUILD_TRANSLATIONS)
    find_package(Qt5 REQUIRED COMPONENTS LinguistTools)
endif()
find_package(Qt5Gui REQUIRED)
find_package(Qt5Widgets REQUIRED)
find_package(Qt5UiTools REQUIRED)

set(TRANSLATION_SOURCES
    main.cpp
    mainwindow.cpp mainwindow.h scenes/mainwindow.ui
    outputdialog.h outputdialog.cpp scenes/outputdialog.ui
)

if (BUILD_EMAIL_TO_TEXT_MODE)
    list(APPEND TRANSLATION_SOURCES emailtextscene.cpp emailtextscene.h scenes/emailtextscene.ui)
endif()
if (BUILD_OCR_MODE)
    list(APPEND TRANSLATION_SOURCES ocrscene.cpp ocrscene.h scenes/ocrscene.ui)
endif()
if (BUILD_OFD_LOCAL_QR_SCAN)
    list(APPEND TRANSLATION_SOURCES adjustpicturedialog.h adjustpicturedialog.cpp scenes/adjustpicturedialog.ui)
endif()

if (BUILD_OFD_LOCAL_QR_SCAN OR BUILD_OFD_BINARYEYE_SCAN)
    list(APPEND TRANSLATION_SOURCES solvecaptchadialog.h solvecaptchadialog.cpp scenes/solvecaptchadialog.ui)
    list(APPEND TRANSLATION_SOURCES ofdscene.cpp ofdscene.h scenes/ofdscene.ui)
endif()

set(PROJECT_SOURCES
    goods/goods.h goods/goods.cpp
    check/check.h check/check.cpp
    parser/parser.h parser/parser.cpp
    parser/module.h parser/module.cpp

    output/output_options.h output/output_options.cpp

    utils/utils.h utils/utils.cpp

    net/net.h net/net.cpp
    settings/settings.h settings/settings.cpp

    ${TRANSLATION_SOURCES}
)

if (BUILD_OCR_MODE)
    list(APPEND PROJECT_SOURCES image/checkimage.h image/checkimage.cpp)
endif()

if (BUILD_OFD_LOCAL_QR_SCAN)
    list(APPEND PROJECT_SOURCES image_redactor/imageredactor.h image_redactor/imageredactor.cpp)
endif()

if (BUILD_OFD_BINARYEYE_SCAN OR BUILD_OFD_LOCAL_QR_SCAN)
    list(APPEND PROJECT_SOURCES exceptions/ofdrequestexception.h exceptions/ofdrequestexception.cpp)
endif()

if (BUILD_OFD_BINARYEYE_SCAN)
    list(APPEND PROJECT_SOURCES http_server/http_server.h http_server/http_server.cpp)
endif()

if (BUILD_TRANSLATIONS)

    set(TS_FILES
        translations/en_US.ts
        translations/ru_RU.ts
    )

    qt5_create_translation(QM_FILES "${TRANSLATION_SOURCES}" ${TS_FILES})
    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/translations.qrc ${CMAKE_CURRENT_BINARY_DIR}/translations.qrc COPYONLY)
    qt5_add_resources(TRANSLATIONQRC ${CMAKE_CURRENT_BINARY_DIR}/translations.qrc)
    add_custom_target(translations ALL DEPENDS ${QM_FILES})
    add_custom_target(resources ALL DEPENDS ${TRANSLATIONQRC})
    add_dependencies(resources translations)
endif()

# Media QRC
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/media.qrc ${CMAKE_CURRENT_BINARY_DIR}/media.qrc COPYONLY)
file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/assets DESTINATION ${CMAKE_CURRENT_BINARY_DIR})
qt5_add_resources(MEDIAQRC ${CMAKE_CURRENT_BINARY_DIR}/media.qrc)
add_custom_target(mediaresource ALL DEPENDS ${MEDIAQRC})

#Scenes QRC
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/scenes.qrc ${CMAKE_CURRENT_BINARY_DIR}/scenes.qrc COPYONLY)
file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/scenes DESTINATION ${CMAKE_CURRENT_BINARY_DIR})
qt5_add_resources(SCENESQRC ${CMAKE_CURRENT_BINARY_DIR}/scenes.qrc)
add_custom_target(scenessource ALL DEPENDS ${SCENESQRC})

set(SOURCES "")

list(APPEND SOURCES ${MEDIAQRC})
list(APPEND SOURCES ${SCENESQRC})

if (BUILD_TRANSLATIONS)
    list(APPEND SOURCES ${TRANSLATIONQRC})
endif()

if(ANDROID)
    add_library(checks-parser SHARED
        ${PROJECT_SOURCES}
        ${SOURCES}
    )
else()
    add_executable(checks-parser
        ${PROJECT_SOURCES}
        ${SOURCES}
    )
endif()

target_link_libraries(checks-parser PRIVATE Qt5::Widgets)

if (BUILD_TRANSLATIONS)
    target_link_libraries(checks-parser PRIVATE Qt5::UiTools)
endif()

if (BUILD_OFD_LOCAL_QR_SCAN)
    target_include_directories(checks-parser PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/image_redactor)
endif()

set(BUNDLE_ID_OPTION MACOSX_BUNDLE_GUI_IDENTIFIER org.foxarmy.checks-parser)

set_target_properties(checks-parser PROPERTIES
    ${BUNDLE_ID_OPTION}
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

include(GNUInstallDirs)
install(TARGETS checks-parser
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

if(WIN32)
    #????
    set(OpenCV_DIR /usr/local/lib/cmake/opencv4)
endif()

if (BUILD_OFD_BINARYEYE_SCAN)
    find_package(PkgConfig)
    pkg_check_modules(QRENCODE REQUIRED libqrencode)
    include_directories(${QRENCODE_INCLUDE_DIRS})
    link_directories(${QRENCODE_LIBRARY_DIRS})
    target_link_libraries(checks-parser PRIVATE ${QRENCODE_LIBRARIES})
endif()
if (BUILD_OFD_LOCAL_QR_SCAN)
    target_link_libraries(checks-parser PRIVATE -lzbar)
endif()

if (BUILD_OCR_MODE)
    target_link_libraries(checks-parser PRIVATE -ltesseract)
endif()

target_link_libraries(checks-parser PRIVATE -lcurl)

if (CMAKE_VERSION VERSION_LESS 3.30)
    find_package(Boost 1.45.0 REQUIRED COMPONENTS regex)
else()
    find_package(Boost 1.45.0 CONFIG REQUIRED COMPONENTS regex)
endif()
include_directories(${Boost_INCLUDE_DIRS})
target_link_libraries(checks-parser PUBLIC ${Boost_LIBRARIES})

if (BUILD_OCR_MODE OR BUILD_OFD_LOCAL_QR_SCAN OR BUILD_OFD_BINARYEYE_SCAN)
    find_package(OpenCV REQUIRED COMPONENTS core imgproc imgcodecs)
    target_link_libraries(checks-parser PRIVATE ${OpenCV_LIBS})
    target_include_directories(checks-parser PUBLIC ${OpenCV_INCLUDE_DIRS})
    include_directories( ${OpenCV_INCLUDE_DIRS} )
endif()

if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 8)
target_link_libraries(checks-parser PRIVATE -lstdc++fs)
endif()